schsh-rrsync

   1 #!/usr/bin/perl
   2 # Name: /usr/local/bin/rrsync (should also have a symlink in /usr/bin)
   3 # Purpose: Restricts rsync to subdirectory declared in .ssh/authorized_keys
   4 # Author: Joe Smith <js-cgi@inwap.com> 30-Sep-2004
   5 # Modified by: Wayne Davison <wayned@samba.org>
   6 # Modified by: Ralf Jung <post@ralfj.de>
   7 use strict;
   8
   9 # use Socket;
  10 use Cwd 'abs_path';
  11 use File::Glob ':glob';
  12
  13 # You may configure these values to your liking.  See also the section
  14 # of options if you want to disable any options that rsync accepts.
  15 use constant RSYNC => '/usr/bin/rsync';
  16
  17 my $Usage = <<EOM;
  18 Use 'command="$0 [-ro] SUBDIR"'
  19         in front of lines in $ENV{HOME}/.ssh/authorized_keys
  20 EOM
  21
  22 our $ro = (@ARGV && $ARGV[0] eq '-ro') ? shift : '';    # -ro = Read-Only
  23 our $subdir = shift;
  24 die "$0: No subdirectory specified\n$Usage" unless defined $subdir;
  25 $subdir = abs_path($subdir);
  26 die "$0: Restricted directory does not exist!\n" if $subdir ne '/' && !-d $subdir;
  27
  28 # The client uses "rsync -av -e ssh src/ server:dir/", and schsh makes the entire rsync call
  29 # the third argument to rrsnc: rrsync (-ro)? SUBDIR COMMAND
  30 # Format of the COMMAND:
  31 # COMMAND=rsync --server          -vlogDtpr --partial . ARG # push
  32 # COMMAND=rsync --server --sender -vlogDtpr --partial . ARGS # pull
  33
  34 my $command = shift;
  35 die "$0: Not invoked via sshd\n$Usage"  unless defined $command;
  36 die "$0: SSH_ORIGINAL_COMMAND='$command' is not rsync\n" unless $command =~ s/^rsync\s+//;
  37 die "$0: --server option is not first\n" unless $command =~ /^--server\s/;
  38 our $am_sender = $command =~ /^--server\s+--sender\s/; # Restrictive on purpose!
  39 die "$0 -ro: sending to read-only server not allowed\n" if $ro && !$am_sender;
  40
  41 ### START of options data produced by the cull_options script. ###
  42
  43 # These options are the only options that rsync might send to the server,
  44 # and only in the option format that the stock rsync produces.
  45
  46 # To disable a short-named option, add its letter to this string:
  47 our $short_disabled = 's';
  48
  49 our $short_no_arg = 'ACDEHIKLORSWXbcdgklmnoprstuvxz'; # DO NOT REMOVE ANY
  50 our $short_with_num = 'B'; # DO NOT REMOVE ANY
  51
  52 # To disable a long-named option, change its value to a -1.  The values mean:
  53 # 0 = the option has no arg; 1 = the arg doesn't need any checking; 2 = only
  54 # check the arg when receiving; and 3 = always check the arg.
  55 our %long_opt = (
  56   'append' => 0,
  57   'backup-dir' => 2,
  58   'bwlimit' => 1,
  59   'checksum-seed' => 1,
  60   'compare-dest' => 2,
  61   'compress-level' => 1,
  62   'copy-dest' => 2,
  63   'copy-unsafe-links' => 0,
  64   'daemon' => -1,
  65   'delay-updates' => 0,
  66   'delete' => 0,
  67   'delete-after' => 0,
  68   'delete-before' => 0,
  69   'delete-delay' => 0,
  70   'delete-during' => 0,
  71   'delete-excluded' => 0,
  72   'delete-missing-args' => 0,
  73   'existing' => 0,
  74   'fake-super' => 0,
  75   'files-from' => 3,
  76   'force' => 0,
  77   'from0' => 0,
  78   'fuzzy' => 0,
  79   'groupmap' => 1,
  80   'iconv' => 1,
  81   'ignore-errors' => 0,
  82   'ignore-existing' => 0,
  83   'ignore-missing-args' => 0,
  84   'inplace' => 0,
  85   'link-dest' => 2,
  86   'list-only' => 0,
  87   'log-file' => 3,
  88   'log-format' => 1,
  89   'max-delete' => 1,
  90   'max-size' => 1,
  91   'min-size' => 1,
  92   'modify-window' => 1,
  93   'no-implied-dirs' => 0,
  94   'no-r' => 0,
  95   'no-relative' => 0,
  96   'no-specials' => 0,
  97   'numeric-ids' => 0,
  98   'only-write-batch' => 1,
  99   'partial' => 0,
 100   'partial-dir' => 2,
 101   'remove-sent-files' => $ro ? -1 : 0,
 102   'remove-source-files' => $ro ? -1 : 0,
 103   'safe-links' => 0,
 104   'sender' => 0,
 105   'server' => 0,
 106   'size-only' => 0,
 107   'skip-compress' => 1,
 108   'specials' => 0,
 109   'stats' => 0,
 110   'suffix' => 1,
 111   'super' => 0,
 112   'temp-dir' => 2,
 113   'timeout' => 1,
 114   'use-qsort' => 0,
 115   'usermap' => 1,
 116 );
 117
 118 ### END of options data produced by the cull_options script. ###
 119
 120 if ($short_disabled ne '') {
 121     $short_no_arg =~ s/[$short_disabled]//go;
 122     $short_with_num =~ s/[$short_disabled]//go;
 123 }
 124 $short_no_arg = "[$short_no_arg]" if length($short_no_arg) > 1;
 125 $short_with_num = "[$short_with_num]" if length($short_with_num) > 1;
 126
 127 my(@opts, @args);
 128 my $in_options = 1;
 129 my $last_opt = '';
 130 my $check_type;
 131 while ($command =~ /((?:[^\s\\]+|\\.[^\s\\]*)+)/g) {
 132   $_ = $1;
 133   if ($check_type) {
 134     push(@opts, check_arg($last_opt, $_, $check_type));
 135     $check_type = 0;
 136   } elsif ($in_options) {
 137     push(@opts, $_);
 138     if ($_ eq '.') {
 139       $in_options = 0;
 140     } else {
 141       die "$0: invalid option: '-'\n" if $_ eq '-';
 142       next if /^-$short_no_arg*(e\d*\.\w*)?$/o || /^-$short_with_num\d+$/o;
 143
 144       my($opt,$arg) = /^--([^=]+)(?:=(.*))?$/;
 145       my $disabled;
 146       if (defined $opt) {
 147         my $ct = $long_opt{$opt};
 148         last unless defined $ct;
 149         next if $ct == 0;
 150         if ($ct > 0) {
 151           if (!defined $arg) {
 152             $check_type = $ct;
 153             $last_opt = $opt;
 154             next;
 155           }
 156           $arg = check_arg($opt, $arg, $ct);
 157           $opts[-1] =~ s/=.*/=$arg/;
 158           next;
 159         }
 160         $disabled = 1;
 161         $opt = "--$opt";
 162       } elsif ($short_disabled ne '') {
 163         $disabled = /^-$short_no_arg*([$short_disabled])/o;
 164         $opt = "-$1";
 165       }
 166
 167       last unless $disabled; # Generate generic failure
 168       die "$0: option $opt has been disabled on this server.\n";
 169     }
 170   } else {
 171     if ($subdir ne '/') {
 172       # Validate args to ensure they don't try to leave our restricted dir.
 173       s{//+}{/}g;
 174       s{^/}{};
 175       s{^$}{.};
 176       die "$0: do not use .. in any path!\n" if m{(^|/)\\?\.\\?\.(\\?/|$)};
 177     }
 178     push(@args, bsd_glob($_, GLOB_LIMIT|GLOB_NOCHECK|GLOB_BRACE|GLOB_QUOTE));
 179   }
 180 }
 181 die "$0: invalid rsync-command syntax or options\n" if $in_options;
 182
 183 @args = ( '.' ) if !@args;
 184
 185 # Note: This assumes that the rsync protocol will not be maliciously hijacked.
 186 exec(RSYNC, @opts, @args) or die "exec(rsync @opts @args) failed: $? $!";
 187
 188 sub check_arg
 189 {
 190   my($opt, $arg, $type) = @_;
 191   $arg =~ s/\\(.)/$1/g;
 192   if ($subdir ne '/' && ($type == 3 || ($type == 2 && !$am_sender))) {
 193     $arg =~ s{//}{/}g;
 194     die "Do not use .. in --$opt; anchor the path at the root of your restricted dir.\n"
 195       if $arg =~ m{(^|/)\.\.(/|$)};
 196     $arg =~ s{^/}{$subdir/};
 197   }
 198   $arg;
 199 }